int numAgents = 1000;
ArrayList cars = new ArrayList();
Graph graph;

void setup() { 
  size(600, 500, JAVA2D);
  graph = new Graph();
  for(int i = 0; i<numAgents; i++)
    cars.add(new Agent((Edge)randomOneOf(graph.edges)));
}

void draw() {
  graph.paint();
  for(int i = 0; i<cars.size(); i++)
    ((Agent)cars.get(i)).step();
  if(frameCount % 10 == 0)
    println("frameRate="+frameRate+" frameCount="+frameCount);
}

// return a random element of this arraylist
Object randomOneOf(ArrayList a) {
  return a.get(randomInt(a.size()));
}

// random one not equal to o
Object randomOtherOneOf(ArrayList a, Object o) {
  Object ret = randomOneOf(a);
  while(ret.equals(o))
    ret = randomOneOf(a);
  return ret;
}

// return random int i in [0,n)
int randomInt(int f) {
  return floor(random (f));
}

// return rgb color w/ r,g,b either 0 or 255
color randomBrightColor() {
  return color(255*randomInt(2), 255*randomInt(2), 255*randomInt(2));
}


/**
 * <pre>
 * Test of Processing for cars and roads for evacuation modeling. 
 * Create a grid of edges and nodes.  
 * Create 1000 cars positioned on 1000 random edges with slightly different random speeds.
 * Optimize the grid drawing by caching the first image of the edges and nodes.
 * The draw loop repositions the cars, changing edges when they get to the end of their current one.
 * </pre>
 */